#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
/*
atmosphere {
    type 1
    //samples 60
    samples 15
    distance 100
    scattering .75
    aa_level 8
    aa_threshold 0.2
    jitter 0.05
}
*/
camera {
  location<0,0,-40>
  look_at<0,0,0>
}

background { color White }
//background { color Black }

light_source { <2000,2000,-2000> color White }
light_source { <-2000,2000,-2000> color White }
//light_source { <0,0,0> color White }

#declare sMetal=texture { Aluminum }
//#declare sMetal=texture { pigment { color White } }

#declare Wave=texture {
    pigment { color rgb <0.55, 0.5, 0.45> }
    normal {
      bumps .6
    }
    finish {
        metallic
        ambient 0.1
        diffuse 0.65
        specular 0.85
        roughness 0.01
        reflection 0.45
        brilliance 1.5
    }
}

#declare tex=texture { pigment { color Black } }
#declare pBrass=texture {
  //pigment { color rgb <0.578, 0.422, 0.195> }
  pigment {
    hexagon pigment{ color MediumSlateBlue },pigment{ color Blue},pigment{ color NavyBlue} //Copper
    scale .2
  }
  normal {
    hexagon .9
    scale .2
  }
  finish {
        metallic
        ambient 0.1
        diffuse 0.8
        brilliance 6.0
        reflection 0.4
        phong 0.8
        phong_size 120
  }
}

#declare R1 = seed(360);

union {
  #declare Count=0;
  #while (Count < 50)
  #declare Rot=<rand(R1)*360,rand(R1)*360,rand(R1)*360>;
  #declare CylnPoint=<50,0,0>;
  //#declare pBlob=<14,0,0>
  //#declare pBlobClose=<10,0,0>
  #declare NewCylnPoint=vrotate(CylnPoint,Rot);
  //#declare BlobPoint=vrotate(pBlob,Rot)
  //#declare BlobClose=vrotate(pBlobClose,Rot)
  #declare RingRad=.5+(rand(R1)*4/4);
  //#declare Rad=12
  #declare Rad=11+(rand(R1)*3);
  #declare CylnRad=1+(rand(R1)*2);
  
  // Base Disc
  intersection {
    difference {
      sphere { <0,0,0>,Rad }
      sphere { <0,0,0>,Rad-.125 }
      cylinder { <0,0,0>,NewCylnPoint,CylnRad }
    }
    cylinder { <0,0,0>,NewCylnPoint,CylnRad+RingRad-.01 }
    //pigment { color rgb<rand(R1)*100/100,rand(R1)*100/100,rand(R1)*100/100> }
    texture { pBrass rotate<0,0,90> rotate Rot }
  }
  // Interior Disc
  intersection {
    difference {
      sphere { <0,0,0>,Rad }
      sphere { <0,0,0>,Rad-.125 }
    }
    cylinder { <0,0,0>,NewCylnPoint,CylnRad }
    //pigment { color Green }
    texture { Wave }
  }
  /*
  blob {
    threshold 1
    sphere { BlobPoint,2,6 }
    sphere { BlobClose,3,6 }
  }
  */
  // under cap
  intersection {
    difference {
      sphere { <0,0,0>,Rad-.125 }
      sphere { <0,0,0>,Rad-.25 }
      //cylinder { <0,0,0>,NewCylnPoint,CylnRad+RingRad-.1 }
    }
    cylinder { <0,0,0>,NewCylnPoint,CylnRad+RingRad }
  }
  // Outside Ring 
  intersection {
    difference {
      sphere { <0,0,0>,Rad+.125 }
      sphere { <0,0,0>,Rad-.125 }
      cylinder { <0,0,0>,NewCylnPoint,CylnRad+RingRad-.1 }
    }
    cylinder { <0,0,0>,NewCylnPoint,CylnRad+RingRad }
  }
  
  // Inside Ring
  
  intersection {
    difference {
      sphere { <0,0,0>,Rad+.125 }
      sphere { <0,0,0>,Rad }
      cylinder { <0,0,0>,NewCylnPoint,CylnRad }
    }
    cylinder { <0,0,0>,NewCylnPoint,CylnRad+.1 }
  }
 
  #declare Count=Count+1; #end
  #declare Count3 = 0; #while (Count3 < 2000)
    cone { <0,9,0>,.5,<0,11.5,0>,.001 
    rotate<rand(R1)*360,rand(R1)*360,rand(R1)*360>
      
    }
  #declare Count3 = Count3 + 1; #end

  sphere { <0,0,0>,10 }
  //pigment { color White }
  texture { sMetal }
}