#include "colors.inc"
#include "textures.inc"
#include "../include/textures.inc"
#include "../include/scene.inc"
#include "ship2.inc"

background { color White }

global_settings{
        assumed_gamma 1.3

        radiosity{
            pretrace_start 1 
            pretrace_end   1
            count 400 
            error_bound 0.05 
            nearest_count 1        // CHANGE - range from 1 to 3 - should correspond with pretrace_end
            recursion_limit 1    // CHANGE
            low_error_factor 1  // leave this
            gray_threshold 0   // leave this
            minimum_reuse 0.015  // leave this
            brightness 1         // leave this
            adc_bailout 0.01/2   // CHANGE - use adc_bailo        
        }
  photons {
    spacing 0.01                 // specify the density of photons
    //count 100000               // alternatively use a total number of photons

    //gather min, max            // amount of photons gathered during render [20, 100]
    //media max_steps [,factor]  // media photons
    //jitter 1.0                 // jitter phor photon rays
    //max_trace_level 5          // optional separate max_trace_level
    //adc_bailout 1/255          // see global adc_bailout
    //save_file "filename"       // save photons to file
    //load_file "filename"       // load photons from file
    //autostop 0                 // photon autostop option
    //radius 10                  // manually specified search radius
    // (---Adaptive Search Radius---)
    //steps 1
    //expand_thresholds 0.2, 40
  }
}


#declare SideView=camera {
  location<0,0,-40>
  look_at<0,0,0>
}

#declare FrontView=camera {
  location<0,20,-55>
  look_at<0,0,0>
  //rotate<90,0,0>
}

#declare TopView=camera {
  location<0,0,-50>
  look_at<0,0,0>
  rotate<90,0,0>
}

//camera { TopView }
camera { FrontView }
//camera { SideView }

light_source { <2000,2000,-2000> color White }
//light_source { <-2000,2000,-2000> color White }
//light_source { <-2000,-2000,-2000> color White }


#declare Window=object {
  difference {
    sphere { <0,0,0>,10 }
    sphere { <0,0,0>,9.75 }
    box { <-1.25,-20,-20>,<20,20,20> }
    box { <-20,-20,-20>,<20,0,20> }
    scale<3,.85,1>
    texture { GlassTex }
  }
}

#declare ShipBody=union {
  union { // Begind Glass
    difference {
      sphere { <0,0,0>,10 }
      box { <0,-20,-20>,<20,20,20> }
      box { <-20,-20,-20>,<-1,20,20> }
      box { <-20,-20,-20>,<20,0,20> }
      scale<3,.85,1>
    }
    difference {
      sphere { <0,0,0>,10 }
      box { <-20,-20,-20>,<0,20,20> }
      box { <-20,-20,-20>,<20,0,20> }
      box { <2,3,-20>,<20,20,20> }
    }
    texture { ShipTex }
  }
  union { // Bottom
    difference {
      sphere { <0,0,0>,10 }
      box { <0,-20,-20>,<20,20,20> }
      box { <-20,0,-20>,<20,20,20> }
      scale<3,.3,1>
      translate<0,-3,0>
    }
    difference {
      sphere { <0,0,0>,10 }
      sphere { <0,0,0>,9 }
      box { <-20,0,-20>,<20,20,20> }
      box { <-20,-20,-20>,<0,20,20> }
      scale<1,.4,1>
      translate<0,-3,0>
    }
    texture { ShipTex }
  }
  union { //Center Strip
    difference {
      cylinder { <0,-.5,0>,<0,-2.5,0>,10 }
      cylinder { <0,0,0>,<0,-3,0>,9.75 }
      box { <0,-20,-20>,<20,20,20> }
      scale<3,1,1>
    }
    difference {
      cylinder { <0,-.5,0>,<0,-2.5,0>,10 }
      cylinder { <0,0,0>,<0,-3,0>,9.75 }
      box { <-20,-20,-20>,<0,20,20> }
    }
    texture { CenterTex }
  }
  union { // Metal Borders
    difference {
      cylinder { <0,0,0>,<0,-.5,0>,10.25 }
      cylinder { <0,-1,0>,<0,1,0>,9.75 }
      box { <0,-20,-20>,<20,20,20> }
      scale<3,1,1>
    }
    difference {
      cylinder { <0,0,0>,<0,-.5,0>,10.25 }
      cylinder { <0,-1,0>,<0,1,0>,9.75 }
      box { <-20,-20,-20>,<0,20,20> }
    }
    difference {
      cylinder { <0,-2.5,0>,<0,-3,0>,10.25 }
      cylinder { <0,0,0>,<0,-4,0>,9.75 }
      box { <0,-20,-20>,<20,20,20> }
      scale<3,1,1>
    }
    difference {
      cylinder { <0,-2.5,0>,<0,-3,0>,10.25 }
      cylinder { <0,0,0>,<0,-4,0>,9.75 }
      box { <-20,-20,-20>,<0,20,20> }
    }
    difference {
      sphere { <0,0,0>,10.25 }
      box { <-1,-20,-20>,<20,20,20> }
      box { <-20,-20,-20>,<-1.25,20,20> }
      box { <-20,-20,-20>,<20,0,20> }
      scale<3,.85,1>
    }
    texture { MetalTex }
  }
}

#declare CockPit=union {
    difference {
      cylinder { <0,-3,0>,<0,-2.75,0>,9.75 }
      box { <20,20,20>,<0,-20,-20> }
      scale<3,1,1>
    }
    difference {
      cylinder { <0,0,0>,<0,-2.75,0>,9.75 }
      cylinder { <0,1,0>,<0,-3,0>,9.7 }
      box { <20,20,20>,<0,-20,-20> }
      scale<3,1,1>
    }
    difference {
      cylinder { <0,0,0>,<-3.8,0,0>,9.75 }
      box { <20,0,20>,<-20,-20,-20> }
      scale<1,.85,1>
    }
    box { <0,0,-9.75>,<-3.8,-2.75,9.75> }
    difference {
      cylinder { <0,0,0>,<0,-2.75,0>,9.7 scale<3,1,1> }
      cylinder { <0,1,0>,<0,-3,0>,9.4 scale<2.5,1,1> }
      box { <30,30,30>,<0,-30,-30> }
    }
    object { Chair scale 5 translate<-15,-3,-3> }
    object { Chair scale 5 translate<-15,-3,3> }
    texture { CockPitTex }
}

#declare GasTank=union {
  cylinder { <0,0,-5>,<0,0,5>,2 }
  sphere { <0,0,0>,2 scale<1,1,.5> translate<0,0,-5> }
  sphere { <0,0,0>,2 scale<1,1,.5> translate<0,0,5> }
  texture { MetalTex }
}

union {
  object { ShipBody }
  object { Window }
  object { CockPit }
  object { LeftEngine scale .3 translate<1,11,0> rotate<-30,0,0> }
  object { RightEngine scale .3 translate<1,11,0> rotate<30,0,0> }
  difference {
    union {
      object { FrontWing translate<-20,-1.5,-6> }
      object { FrontWing rotate<180,0,0> translate<-20,-1.5,6> }
      object { RearWing translate<-8,-1.5,0> }
      object { Vent translate<-9.5,-1.5,-10> }
      object { Vent translate<-12.5,-1.5,-10> }
      object { Vent rotate<0,180,0> translate<-9.5,-1.5,10> }
      object { Vent rotate<0,180,0> translate<-12.5,-1.5,10> }
    }
    cylinder { <0,0,0>,<0,-2.75,0>,9.75 scale<3,1,1> }
  }
  object { GasTank translate<5,5,0> }
  rotate<0,-60,0>
  translate<5,0,0>
  //rotate<0,-90,0>
  //translate<7,0,0>
}